| 套件 | flash.globalization |
| 類別 | public final class DateTimeFormatter |
| 繼承 | DateTimeFormatter  Object |
| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
您可使用兩種方式選擇日期時間格式：使用預先定義的樣式或自訂樣式。對大部分的應用程式而言，應使用 DateTimeStyle 常數 (LONG、MEDIUM、NONE 或 SHORT) 所指定的預先定義樣式。這些常數會指定所要求地區設定的預設樣式，或以使用者作業系統設定為基礎的預設樣式。
例如，下列程式碼會使用預設簡短日期格式建立日期字串：
var df:DateTimeFormatter = new DateTimeFormatter(LocaleID.DEFAULT, DateTimeStyle.SHORT, DateTimeStyle.NONE);
var currentDate:Date = new Date();
var shortDate:String = df.format(currentDate);
建立此類別的實體後，若作業系統支援要求的地區設定，則會根據要求的地區設定的慣例和預設值與建構函式的 dateStyle 和 timeStyle 參數，設定實體屬性。若無法使用所要求的地區設定，則會根據後援或預設系統地區設定 (可使用 actualLocaleIDName 屬性擷取) 設定屬性。
此類別還有其他方法，可取得月份與星期別的當地語系化字串，並擷取每週第一天，以便在月曆挑選器或其他類似應用程式中使用。
由於所用的使用者設定、作業系統提供的格式化樣式，以及不支援所要求地區設定時所用的後援地區設定之不同，即使是使用相同的地區設定 ID，不同使用者也會看到不同的格式化結果。
相關 API 元素
隱藏繼承公用屬性
顯示繼承公用屬性| 屬性 | 定義自 | ||
|---|---|---|---|
| actualLocaleIDName : String [唯讀]
此 DateTimeFormatter 物件所使用的實際地區設定 ID 名稱。 | DateTimeFormatter | ||
 | constructor : Object
類別物件的參照或是特定物件實體的建構函數。 | Object | |
| lastOperationStatus : String [唯讀]
此 DateTimeFormatter 物件執行之上一個作業的狀態。 | DateTimeFormatter | ||
| requestedLocaleIDName : String [唯讀]
傳送到此 DateTimeFormatter 物件建構函式的所要求地區設定 ID 名稱。 | DateTimeFormatter | ||
| 方法 | 定義自 | ||
|---|---|---|---|
DateTimeFormatter(requestedLocaleIDName:String, dateStyle:String = "long", timeStyle:String = "long")
建構新 DateTimeFormatter 物件，以根據指定地區設定的慣例和所提供的日期與時間格式樣式，格式化日期與時間。 | DateTimeFormatter | ||
針對解譯為使用者本地時間 (使用 Date 物件的本地時間組件，如：date、day, fullYear、hours、minutes、month 和 seconds) 的 Date 物件，格式化顯示字串。 | DateTimeFormatter | ||
根據 dateStyle、timeStyle 或 date time 樣式，針對解譯為 UTC 時間 (使用 Date 物件的 UTC 組件，如：dateUTC、dayUTC、fullYearUTC、hoursUTC、minutesUTC、monthUTC 和 secondsUTC) 的 Date 物件，格式化顯示字串。 | DateTimeFormatter | ||
[靜態]
列出此類別支援的所有地區設定 ID 名稱。 | DateTimeFormatter | ||
取得此 DateTimeFormatter 實體的日期樣式。 | DateTimeFormatter | ||
傳回此 DateTimeFormatter 物件用來格式化日期與時間的樣式字串。 | DateTimeFormatter | ||
傳回對應到此地區設定和月曆系統中每週第一天的整數。 | DateTimeFormatter | ||
擷取包含目前月曆系統月份名稱的當地語系化字串清單。 | DateTimeFormatter | ||
取得此 DateTimeFormatter 實體的時間樣式。 | DateTimeFormatter | ||
擷取包含目前月曆系統星期別名稱的當地語系化字串清單。 | DateTimeFormatter | ||
|
指出物件是否有已定義的指定屬性。 | Object | |
|
指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。 | Object | |
|
指出指定的屬性是否存在，以及是否可列舉。 | Object | |
設定此 DateTimeFormatter 物件用來格式化日期與時間的樣式字串。 | DateTimeFormatter | ||
設定此 DateTimeFormatter 實體的日期和時間樣式。 | DateTimeFormatter | ||
|
為迴圈作業設定動態屬性的可用性。 | Object | |
|
傳回代表此物件的字串，根據地區特定慣例進行格式化。 | Object | |
|
會傳回指定之物件的字串形式。 | Object | |
|
會傳回指定之物件的基本值。 | Object | |
actualLocaleIDName | 屬性 |
actualLocaleIDName:String [唯讀] | 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
此 DateTimeFormatter 物件所使用的實際地區設定 ID 名稱。
根據作業系統與 requestedLocaleIDName 參數傳送到 Collator() 建構函式的值，此值有三種可能性。
- 若要求的地區設定不是
LocaleID.DEFAULT，而且作業系統支援要求的地區設定，則傳回的名稱會與requestedLocaleIDName屬性相同。 - 若使用
LocaleID.DEFAULT當作建構函式requestedLocaleIDName參數的值，則會使用使用者作業系統指定的目前地區設定名稱。LocaleID.DEFAULT值會將使用者的自訂設定保留於作業系統中。即使兩個地區設定 ID 名稱是相同的，傳送明確的值作為requestedLocaleIDName參數所得的結果，也未必與使用LocaleID.DEFAULT相同。使用者可能在自己的電腦上已有自訂的地區設定，若要求明確的地區設定 ID 名稱而不是使用LocaleID.DEFAULT的話，您的應用程式不會擷取這些自訂設定。 - 若系統不支援建構函式所指定的
requestedLocaleIDName，則會提供後援地區設定 ID 名稱。
實作
public function get actualLocaleIDName():String相關 API 元素
lastOperationStatus | 屬性 |
requestedLocaleIDName | 屬性 |
requestedLocaleIDName:String [唯讀] | 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
傳送到此 DateTimeFormatter 物件建構函式的所要求地區設定 ID 名稱。
若使用 LocaleID.DEFAULT 值，則傳回的名稱會是 "i-default"。若採用後援地區設定，則所用的實際地區設定可能與要求的地區設定不同。您可以使用 actualLocaleIDName 屬性擷取實際地區設定名稱。
實作
public function get requestedLocaleIDName():String相關 API 元素
DateTimeFormatter | () | 建構函式 |
public function DateTimeFormatter(requestedLocaleIDName:String, dateStyle:String = "long", timeStyle:String = "long")| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
建構新 DateTimeFormatter 物件，以根據指定地區設定的慣例和所提供的日期與時間格式樣式，格式化日期與時間。日期和時間樣式用來設定預先定義的日期和時間格式化樣式，地區設定會根據作業系統樣式而有所不同。
此建構函式會判斷目前的作業系統是否支援要求的地區設定 ID 名稱。若不支援，則會改用後援地區設定。您可以從 actualLocaleIDName 屬性判斷後援地區設定 ID 的名稱。
若 requestedLocaleIDName、dateStyle 或 timeStyle 其中一個參數使用後援，則會設定 lastOperationStatus 屬性指示後援類型。
若要根據使用者目前作業系統的偏好設定進行格式化，請將 requestedLocaleIDName 參數中的 LocaleID.DEFAULT 值傳送到建構函式。
當建構函式被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
若要求的地區設定 ID 名稱無法使用，則 lastOperationStatus 會被設為下列之一：
LastOperationStatus.USING_FALLBACK_WARNINGLastOperationStatus.USING_DEFAULT_WARNING
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
如需有關上方列出的警告以及 lastOperationStatus 屬性的其他可能值的詳細資訊，請參閱 LastOperationStatus 類別的說明。
requestedLocaleIDName:String — 判斷日期或時間格式時要使用的偏好地區設定 ID 名稱。
| |
dateStyle:String (default = "long")
| |
timeStyle:String (default = "long")
|
擲回值
ArgumentError — 若 dateStyle 或 timeStyle 參數非有效的 DateTimeStyle 常數。
| |
TypeError — 若 dateStyle 或 timeStyle 參數為 null。
|
相關 API 元素
format | () | 方法 |
public function format(dateTime:Date):String| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
針對解譯為使用者本地時間 (使用 Date 物件的本地時間組件，如：date、day, fullYear、hours、minutes、month 和 seconds) 的 Date 物件，格式化顯示字串。會使用此 DateTimeFormatter 實體中指定的地區設定 ID 和日期與時間樣式慣例，或自訂日期與時間樣式，完成格式化動作。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
參數
dateTime:Date — 要格式化的 Date 值。有效範圍是從 1601 年 1 月 1 日到 30827 年 12 月 31 日。
|
String — 代表日期或時間值的格式化字串。
|
相關 API 元素
formatUTC | () | 方法 |
public function formatUTC(dateTime:Date):String| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
根據 dateStyle、timeStyle 或 date time 樣式，針對解譯為 UTC 時間 (使用 Date 物件的 UTC 組件，如：dateUTC、dayUTC、fullYearUTC、hoursUTC、minutesUTC、monthUTC 和 secondsUTC) 的 Date 物件，格式化顯示字串。會使用此 DateTimeFormatter 實體中指定的地區設定 ID 和日期與時間樣式慣例，或自訂日期與時間樣式，完成格式化動作。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
參數
dateTime:Date — 要格式化的 Date 值。有效範圍是從 1601 年 1 月 1 日到 30827 年 12 月 31 日。
|
String — 代表日期或時間值的格式化字串。
|
相關 API 元素
getAvailableLocaleIDNames | () | 方法 |
public static function getAvailableLocaleIDNames():Vector.<String>| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
列出此類別支援的所有地區設定 ID 名稱。
若目前的作業系統不支援此類別，此方法會傳回 null 值。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
Vector.<String> — 包含此類別支援的所有地區設定 ID 名稱之字串向量。
|
相關 API 元素
getDateStyle | () | 方法 |
public function getDateStyle():String| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
取得此 DateTimeFormatter 實體的日期樣式。日期樣式是用來從作業系統擷取預先定義的日期格式化樣式。DateTimeFormatter() 建構函式、setDateTimeStyles() 方法或 setDateTimePattern() 方法，都可設定日期樣式值。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
String — 此格式化程式的日期樣式字串。
可能的值有：
|
相關 API 元素
getDateTimePattern | () | 方法 |
public function getDateTimePattern():String| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
傳回此 DateTimeFormatter 物件用來格式化日期與時間的樣式字串。
可使用下列三種方式設定此樣式：
- 透過建構函式中所用的
dateStyle和timeStyle參數 - 透過
setDateTimeStyles()方法 - 透過
setDateTimePattern()方法。
如需樣式語法的說明，請參閱 setDateTimePattern() 方法。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
String — 包含此 DateTimeFormatter 物件用來格式化日期與時間的樣式之字串。
|
相關 API 元素
getFirstWeekday | () | 方法 |
public function getFirstWeekday():int| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
傳回對應到此地區設定和月曆系統中每週第一天的整數。0 值對應到星期日、1 對應到星期一，依此類推，6 對應到星期六。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
int — 對應到此地區設定和月曆系統中每週第一天的整數。
|
相關 API 元素
getMonthNames | () | 方法 |
public function getMonthNames(nameStyle:String = "full", context:String = "standalone"):Vector.<String>| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
擷取包含目前月曆系統月份名稱的當地語系化字串清單。清單中第一個元素是年中第一個月份的名稱。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
參數
nameStyle:String (default = "full")
| |
context:String (default = "standalone")
|
Vector.<String> — 包含指定地區設定、名稱樣式和內容之月份名稱的當地語系化字串向量。向量中位於索引 0 的第一個元素是年中第一個月份的名稱；下一個元素是年中第二個月份的名稱，依此類推。
|
擲回值
TypeError — 若 nameStyle 或 context 參數為 null。
|
相關 API 元素
getTimeStyle | () | 方法 |
public function getTimeStyle():String| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
取得此 DateTimeFormatter 實體的時間樣式。時間樣式是用來從作業系統擷取預先定義的時間格式化樣式。DateTimeFormatter() 建構函式、setDateTimeStyles() 方法或 setDateTimePattern() 方法，都可設定時間樣式值。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
String — 此格式化程式的時間樣式字串。
可能的值有：
|
相關 API 元素
getWeekdayNames | () | 方法 |
public function getWeekdayNames(nameStyle:String = "full", context:String = "standalone"):Vector.<String>| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
擷取包含目前月曆系統星期別名稱的當地語系化字串清單。清單中的第一個元素代表「星期日」的名稱。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
參數
nameStyle:String (default = "full")
| |
context:String (default = "standalone")
|
Vector.<String> — 包含指定地區設定、名稱樣式和內容之月份名稱的當地語系化字串向量。向量中位於索引 0 的第一個元素是「星期日」的名稱，第二個元素是「星期一」的名稱，依此類推。
|
擲回值
TypeError — 若 nameStyle 或 context 參數為 null。
|
相關 API 元素
setDateTimePattern | () | 方法 |
public function setDateTimePattern(pattern:String):void| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
設定此 DateTimeFormatter 物件用來格式化日期與時間的樣式字串。
可使用下列三種方式設定格式化日期所用的樣式：
- 透過建構函式中所用的
dateStyle和timeStyle參數 - 透過
setDateTimeStyles()方法 - 透過此
setDateTimePattern()方法。
此方法有個副作用，就是會覆寫此 DateTimeFormatter 物件的目前時間與日期樣式，並將其設為值 DateTimeStyle.CUSTOM。
定義如何格式化日期和時間的樣式字串。樣式包含的字母序列，會在格式化字串中被取代為日期和時間值。例如，在樣式「yyyy/MM」中，「yyyy」字元會被取代為四位數年份，接著「/」字元，「MM」會被取代為二位數月份。
樣式中使用的許多字母都可重複多次，以產生不同輸出，如下表所說明。
若序列超出樣式支援的字母數上限，會對應回該樣式字母支援的最長序列。例如：
- MMMMMM 會被取代為 MMMM
- dddd 會被取代為 dd
- EEEEEEE 會被取代為 EEEE
- aa 會被取代為 a
- hhh 會被取代為 hh
- mmmm 會被取代為 mm
理論上，樣式最多可包含 255 個字元，但有些平台的限制更為嚴格。若樣式超出樣式字元限制，lastOperationStatus 屬性會設為值 LastOperationStatus.PATTERN_SYNTAX_ERROR。
並非所有作業系統都支援所有可能的樣式。若有平台不支援某樣式，則會使用後援樣式，並設定 lastOperationStatus 屬性以指示使用後援。若無法提供合理的後援樣式，則會使用空字串，並設定 lastOperationStatus 屬性以表示不支援該樣式。
下表說明有效樣式字母及其意義。
| 樣式字母 | 說明 |
| G | 紀元。會被目前日期與月曆的紀元字串取代。並非所有作業系統都支援此樣式。在不支援紀元的作業系統中，輸入樣式的字母會被取代為空字串。
紀元樣式可有一至五個字母，解譯如下：
使用「西曆」的範例 (對支援此樣式的作業系統而言)：
|
| y | 年。若樣式字母數為二，會顯示年份的最後兩位數，否則字母數會決定位數。若年份值所需位數超過字母數所提供的位數，就會提供完整年份值。若字母數多過值所需的位數，則會以零填補年份值。下列清單顯示年份為 1 與 2005 的結果。
範例：
|
| M | 年中月份。月份樣式可有一至五個字母，解譯如下：
範例：
|
| d | 月份日期別。月中日期樣式可有一或二個字母，解譯如下：
範例：
|
| E | 星期別。星期別樣式可有一到五個字母，解譯如下：
範例：
|
| Q | 季。某些平台不支援此樣式。季樣式可有一至四個字母，解譯如下：
範例 (對支援此樣式的作業系統而言)：
|
| w | 年中週別。某些平台不支援此樣式。年中週別樣式可有一至二個字母，解譯如下：
以一年的第二週為例 (對支援此樣式的作業系統而言)：
|
| W | 月中週別。某些平台不支援此樣式。此樣式只允許一個字母。
以七月的第二週為例 (對支援此樣式的作業系統而言)：
|
| D | 年中日期別。某些平台不支援此樣式。此樣式可有一至三個字母。
以一年的第二天為例 (對支援此樣式的作業系統而言)：
|
| F | 行事曆月份中當天的週次。例如，如果格式化 10 月第三個星期一的日期時，此元素會顯示 "3"。此樣式只允許一個字母。
以七月的第二個星期三為例 (對支援此樣式的作業系統而言)：
|
| a | AM/PM 指示器。此樣式只允許一個字母，a 或 p。
範例：
|
| h | 12 小時格式 [1 - 12] 的日中小時別。此樣式必須為一或二個字母。
範例：
|
| H | 24 小時格式 [0 - 23] 的日中小時別。此樣式必須為一或二個字母。
範例：
|
| K | 12 小時格式 [0 - 11] 的日中小時別。此樣式必須為一或二個字母。並非所有作業系統都支援此樣式。
範例 (對支援此樣式的作業系統而言)：
|
| k | 24 小時格式 [1 - 24] 的日中小時別。此樣式必須為一或二個字母。並非所有作業系統都支援此樣式。
範例 (對支援此樣式的作業系統而言)：
|
| m | 小時中的分鐘別 [0 - 59]。此樣式必須為一或二個字母。
範例：
|
| s | 分鐘中的秒數別 [0 - 59]。此樣式必須為一或二個字母。
範例：
|
| S | 毫秒。這個樣式必須為一到五個字母。數值會根據所用的字母數而四捨五入。當使用五個字元 (SSSSS) 時，它代表含小數的毫秒。
範例：
|
| z | 時區。不參照特定地區，但考慮標準或日光節約時間，將時區表示為字串。並非所有作業系統都支援此樣式。在不支援時區樣式的作業系統中，輸入樣式的字母會被取代為空字串。在支援此樣式的作業系統上，並非所有地區設定都具有已定義的字串。未定義的地區設定會退回當地語系化的 GMT 格式，如 GMT-08:00 或 GW-08:00
此時區樣式必須有一至四個字母，解譯如下：
範例 (對支援此格式的作業系統而言)：
|
| Z | 時區。以和 GMT 的偏移值表示時區。並非所有作業系統都支援此樣式。在不支援時區樣式的作業系統中，輸入樣式的字母會被取代為空字串。
此時區樣式必須有一至四個字母，解譯如下：
範例 (對支援此格式的作業系統而言)：
|
| v | 時區。不指特定地區或區分日光節約時間或標準時間的一般時區字串。並非所有作業系統都支援此樣式。在不支援時區樣式的作業系統中，輸入樣式的字母會被取代為空字串。在不支援此樣式的作業系統中，若無法使用當地語系化名稱，會提供後援字串。
此時區樣式必須有一或四個字母，解譯如下：
範例 (對支援此格式的作業系統而言)：
|
| '其他文字' | 此樣式字串中可包含文字和標點符號。但 a 到 z 與 A 到 Z 等字元保留為語法字元，在格式化字串中必須包含於單引號中。若要在結果字串中包含單引號，請在樣式字串中使用兩個單引號。兩個單引號可出現在樣式字串括住的部份裡面或外面。未成對的單引號會在字串結尾被截斷。
範例：
|
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
參數
pattern:String |
擲回值
TypeError — 若樣式參數為 null。
|
相關 API 元素
setDateTimeStyles | () | 方法 |
public function setDateTimeStyles(dateStyle:String, timeStyle:String):void| 語言版本: | ActionScript 3.0 |
| 執行階段版本: | Flash Player 10.1, AIR 2 |
設定此 DateTimeFormatter 實體的日期和時間樣式。日期和時間樣式可用來設定預先定義的日期和時間格式化樣式，地區設定會根據作業系統樣式而有所不同。此方法會取代使用 DateTimeFormatter() 建構函式或 setDateTimePattern() 方法所設定的樣式。同時會根據所設定的樣式，更新日期和時間樣式。
當此方法被呼叫並成功完成時，lastOperationStatus 屬性會被設為：
LastOperationStatus.NO_ERROR
否則，lastOperationStatus 屬性會被設為 LastOperationStatus 類別中定義的常數之一。
參數
dateStyle:String — 指定格式化日期時要使用的樣式。值會對應到 DateTimeStyle 類別所列舉的值之一：
| |
timeStyle:String — 指定格式化時間時要使用的樣式。值會對應到 DateTimeStyle 類別所列舉的值之一：
|
擲回值
ArgumentError — 若 dateStyle 或 timeStyle 參數非有效的 DateTimeStyle 常數。
| |
TypeError — 若 dateStyle 或 timeStyle 參數為 null。
|
相關 API 元素
本範例使用下列地區設定：英文 (美國)、法文 (法國)、西班牙文 (西班牙)。
此範例會為清單中的每一個地區設定執行以下動作：
- 使用預設樣式 (dateStyle 為 long，timeStyle 為 long) 建立 DateTimeFormatter 物件
- 使用預設的完整日期樣式，設定目前日期和時間的格式。
- 使用
DateTimeStyle.NONE和DateTimeStyle.SHORT常數，變更成只有時間的簡短日期樣式。 - 使用只有時間的簡短日期樣式，設定目前日期和時間的格式。
package {
import flash.display.Sprite;
import flash.globalization.DateTimeFormatter;
import flash.globalization.DateTimeStyle;
public class DateTimeFormatterExample extends Sprite
{
private var localeList:Array = new Array("en-US", "fr-FR", "es-ES");
public function DateTimeFormatterExample()
{
var date:Date = new Date();
for each (var locale:String in localeList) {
var dtf:DateTimeFormatter = new DateTimeFormatter(locale);
trace('\n' + "LocaleID requested=" + dtf.requestedLocaleIDName
+ "; actual=" + dtf.actualLocaleIDName);
var longDate:String = dtf.format(date);
trace(longDate + " (" + dtf.getDateTimePattern() + ")");
dtf.setDateTimeStyles(DateTimeStyle.NONE, DateTimeStyle.SHORT);
var shortDate:String = dtf.format(date);
trace(shortDate + " (" + dtf.getDateTimePattern() + ")");
}
}
}
}
此範例會為清單中的每一個地區設定執行以下動作：
- 建立三個輸入以及輸出文字欄位。
- 使用美國英文地區設定來建立 DateTimeFormatter 物件。
- 呼叫
configureTextField()函數，它會設定文字欄位的位置和大小以及將偵聽程式加到patternField物件。 - 當使用者在
patternField文字欄位輸入樣式後，textInputHandler函數會使用該樣式來設定日期和時間的格式，並在輸出文字欄位中顯示結果和lastOperationStatus值。
package {
import flash.display.Sprite;
import flash.events.Event;
import flash.globalization.DateTimeFormatter;
import flash.text.*;
public class DateTimePatternExample extends Sprite
{
private var patternField:TextField = new TextField();
private var resultField:TextField = new TextField();
private var statusField:TextField = new TextField();
private var date:Date = new Date();
private var dtf:DateTimeFormatter = new DateTimeFormatter("en-US");
private function configureTextField():void
{
patternField.type = TextFieldType.INPUT;
patternField.width = 300;
patternField.height = 20;
patternField.background = true;
patternField.border = true;
resultField.y = 40;
resultField.width = 300;
resultField.height = 20;
statusField.y = 80;
statusField.width = 300;
statusField.height = 20;
addChild(patternField);
addChild(resultField);
addChild(statusField);
patternField.addEventListener(Event.CHANGE,textInputHandler);
}
private function textInputHandler(event:Event):void
{
dtf.setDateTimePattern(patternField.text);
statusField.text = dtf.lastOperationStatus;
resultField.text = dtf.format(date);
}
public function DateTimePatternExample()
{
configureTextField();
}
}
}
Tue Jun 12 2018, 03:47 PM Z